有些GM看到脱机外挂非常的头痛，因为它影响到了游戏平衡。现在我们不用再郁闷了，以下脚本就是帮你解决脱机外挂的烦恼。

此脚本所需要配置的文件如下：

登陆脚本: \Mirserver\Mir200\Envir\MapQuest_def\QManage.txt

机器人脚本: \Mirserver\Mir200\Envir\Robot_def\AutoRunRobot.txt

机器人配置: \Mirserver\Mir200\Envir\Robot_def\RobotManage1.txt

GM后台脚本(我想这个就不用多说了，每个服务端都是不同的，大家因该知道的。)

=============================================================================

首先打开登陆脚本

[@login]
;@login下面是玩家登陆游戏所执行的脚本
#act
goto @hxgwgbf

在内容最下面加入以下这段：

[@hxgwgbf]
#IF
check [432] 0
#say
╔------------------------------------------------------╗\
┆欢迎进入『<$SERVERNAME>』游戏服务器！                 ┆\
┆本服务器为了防止离线脱机外挂,影响游戏平衡！           ┆\
┆所有玩家登陆游戏必须得<激活登陆>否则将作离线挂机处理！┆\
┆系统将每1分钟检查一次,没有激活登陆者,将自动踢出游戏！ ┆\
┆                                                      ┆\
┆                 <激 活 登 陆/@iyitwgbf>              ┆\
╚------------------------------------------------------╝
#ACT
break
#IF
check [432] 1
#ACT
set [432] 0
#say
╔------------------------------------------------------╗\
┆欢迎进入『<$SERVERNAME>』游戏服务器！                 ┆\
┆本服务器为了防止离线脱机外挂,影响游戏平衡！           ┆\
┆所有玩家登陆游戏必须得<激活登陆>否则将作离线挂机处理！┆\
┆系统将每1分钟检查一次,没有激活登陆者,将自动踢出游戏！ ┆\
┆                                                      ┆\
┆                 <激 活 登 陆/@iyitwgbf>              ┆\
╚------------------------------------------------------╝
[@iyitwgbf]
#act
set [432] 1
SENDMSG 6 系统提示：激活登陆成功,祝您游戏愉快！
Close

[@踢玩家]
#IF
check [086] 1
check [432] 0
#act
set [086] 0
mapmove B311
messagebox 由于您两次没有激话登陆，你将被关押！
break
#IF
check [432] 0
;检查是否激活登陆
ONLINELONGMIN > 1
;检查玩家上线时间是否大于1
#ACT
set [086] 1
messagebox 由于您没有激话登陆，系统将自动将您踢出游戏！
Gmexecute Kick self

=============================================================================

然后打开机器人脚本

在里面加入一下内容：

#AutoRun NPC MIN 1 @防脱机
;每1分钟执行一次 @防脱机

=============================================================================

再接着打开机器人配置脚本

在里面加入一下内容：

[@防脱机]
#IF
equal G10 0
;检查是否开启了防脱机系统
#ACT
Gmexecute 开始提问 @踢玩家

=============================================================================

现在到GM后台脚本中加入下面这段内容：

<开启关闭防脱机系统/@开关防脱机系统>

[@开关防脱机系统]
#IF
ISADMIN
equal G10 0
#ACT
mov G10 1
SENDMSG 6 系统提示：防脱机系统关闲！
Close
break
#IF
ISADMIN
equal G10 1
#ACT
mov G10 0
SENDMSG 6 系统提示：防脱机系统开启！

=============================================================================

这个脚本的作用就是，每个玩家在登陆的时候要必须激活，而且系统会每1分钟检查一次，没有激活登陆的就会被踢下线。如果玩家被踢下线后，再次登陆时还不激活的话系统将会把玩家关押到地图B311（也是就监狱地图，现在一般的服务端都有这个地图），想要出此地图，玩家必须要自己上线在里面挂半小时。

还有大家注意一下，这个脚本是用了两个变量[432]与G10变量，你要确认请服务器中这两个变量没在使用才能使用这个脚本。